Notesclub

created by hec & contributors

terms privacy

DP23a - Funkcionális programozás, 2. gyakorlat

dp23a-fp2gy-feladatsor.livemd

@FlyinPancake

dekla

Share to X

Share to Bluesky

More notebooks

DP23a - Funkcionális programozás, 2. gyakorlat

Konvenciók, jelölések

A gyakorlatok anyaga szakaszokra van felosztva, minden szakaszban a bevezetés után néhány feladatot definiálunk, néha megoldott feladatokat is bemutatunk.

Halványzöld peremű, fekete hátterű cellában (a továbbiakban: specifikációs cella) van
a szükséges „keretezéssel”, azaz a modul- és függvénydefinícióval együtt a megírandó
függvény típusspecifikációja, valamint néhány teszthívás is. Ebbe a cellába nem lehet
beleírni (csak szerkesztő módban), de a tartalmát ki lehet jelölni, lehet másolni.

Rózsaszín hátterű cellába írjuk az esetleges korlátozásokat: ne használja ezt, ne csinálja azt stb.

Halványzöld hátterű cellában jelennek meg a magyarázataink, illetve a javaslataink egyes feladatok megoldására. Az utóbbiak gyakran el vannak rejve: a Súgó feliratra kattintva jelennek meg.

Az egymást kölcsönösen kizáró minták használata...

Súgó Ezt és ezt javasoljuk a függvény megírásához.

A feladatot megoldó függvényt, kifejezést egy Elixir-cellába írja be: a felugó menüben a + Elixir feliratra kattintva hozzon létre egy új cellát, másolja be a specifikációs cella tartalmát, majd írja meg és értékelje ki a specifikált függvényt vagy a kért kifejezést.

Feladatok listák rekurzív feldolgozására

Lista kettévágása

Két változatban is írja meg a split/2 függvényt: az első változatban ne használjon segédfüggvényt, és így akkumulátort sem, a másodikban pedig használjon segédfüggvényt akkumulátorral.

Ne használja az Enum.split és az Enum.reverse függvényeket a split/2 függvény megvalósítására! (De bármilyen könyvtári függvényt használhat az eredmény ellenőrzésére.)

defmodule Split do
  @spec split(xs :: [any()], n :: integer()) :: {ps :: [any()], ss :: [any()]}
  # Az xs lista n hosszú prefixuma (első n eleme) ps, length(xs)-n
  # hosszú szuffixuma (első n eleme utáni része) pedig ss
  def split(xs, n) do
  ...
  end
end
IO.puts(Split.split([10, 20, 30, 40, 50], 3) === {[10, 20, 30], [40, 50]})
IO.puts(IO.inspect(Split.split(~c"egyedem-begyedem", 8)) === Enum.split(~c"egyedem-begyedem", 8))
IO.puts(IO.inspect(Split.split(~c"papás-mamás", 6)) === Enum.split(~c"papás-mamás", 6))
IO.puts(Split.split(~c"nem_vágom", 0) === Enum.split(~c"nem_vágom", 0))
IO.puts(Split.split(~c"", 10) === Enum.split(~c"", 10))
IO.puts(Split.split(~c"", 0) === Enum.split(~c"", 0))

A második változathoz írjon segédfüggvényt egy lista megfordítására is, hiszen nem használhatja az Enum.reverse függvényeket.

defmodule Split do
  @spec split(xs :: [any()], n :: integer()) :: {ps :: [any()], ss :: [any()]}
  # Az xs lista n hosszú prefixuma (első n eleme) ps, length(xs)-n
  # hosszú szuffixuma (első n eleme utáni része) pedig ss
  defp shelper(xs, 0, acc), do: {acc, xs}
  defp shelper([], _, acc), do: {acc, []}

  defp shelper(xs, n, acc) do
    [hd | r] = xs
    shelper(r, n - 1, [hd | acc])
  end

  def split(xs, n) do
    {ps, ss} = shelper(xs, n, [])
    {reverse(ps), ss}
  end

  defp revhelper([], acc), do: acc

  defp revhelper(xs, acc) do
    [hd | r] = xs
    newacc = [hd | acc]
    revhelper(r, newacc)
  end

  def reverse(xs) do
    revhelper(xs, [])
  end
end

IO.puts(Split.split([10, 20, 30, 40, 50], 3) === {[10, 20, 30], [40, 50]})
IO.puts(IO.inspect(Split.split(~c"egyedem-begyedem", 8)) === Enum.split(~c"egyedem-begyedem", 8))
IO.puts(IO.inspect(Split.split(~c"papás-mamás", 6)) === Enum.split(~c"papás-mamás", 6))
IO.puts(Split.split(~c"nem_vágom", 0) === Enum.split(~c"nem_vágom", 0))
IO.puts(Split.split(~c"", 10) === Enum.split(~c"", 10))
IO.puts(Split.split(~c"", 0) === Enum.split(~c"", 0))

IO.puts(~c"badadan" |> Enum.reverse() === Split.reverse(~c"badadan"))

true
{~c"egyedem-", ~c"begyedem"}
true
{[112, 97, 112, 225, 115, 45], [109, 97, 109, 225, 115]}
true
true
true
true
true

:ok

# Imperative
# l = Enum.zip([0..(length(xs) - 1) ,xs]) 
# |> Enum.map(fn {pos, x} -> 
#   if pos < n do
#     {:pre, x}
#   else
#     {:post, x}
#   end
# end)
# ps = l|>Enum.filter(fn {p, _} -> p == :pre end) |> Enum.map(fn {_, x} -> x end)
# ss = l|>Enum.filter(fn {p, _} -> p == :post end) |> Enum.map(fn {_, x} -> x end)
# {ps, ss}

# Pattern Matching
# defmodule Split do
#   @spec split(xs :: [any()], n :: integer()) :: {ps :: [any()], ss :: [any()]}
#   # Az xs lista n hosszú prefixuma (első n eleme) ps, length(xs)-n
#   # hosszú szuffixuma (első n eleme utáni része) pedig ss
#   def split(xs, 0), do: {[],xs}
#   def split([], _), do: {[],[]}
#   def split(xs, n) do
#     [hd | rest] = xs
#     {phd, pp} = split(rest, n-1)
#     {[hd| phd],pp }
#   end
# end

nil

Lista adott feltételt kielégítő elemeiből álló prefixuma

Két változatban is írja meg a takewhile/2 függvényt: az első változatban ne használjon segédfüggvényt, és így akkumulátort sem, a másodikban pedig használjon segédfüggvényt akkumulátorral.

Ne használja az Enum.take_while/2 függvényt a takewhile/2 függvény megvalósítására! (De bármilyen könyvtári függvényt használhat az eredmény ellenőrzésére.)

defmodule Take do
  @spec takewhile(xs :: [any()], f :: (any() -> boolean())) :: rs :: [any()]
  def takewhile(xs, f) do
  ...
  end
end
IO.puts(Take.takewhile(~c"álom12" ++ [:a] ++ [~c"34brigád"], &is_integer/1) === ~c"álom12")
IO.puts(Take.takewhile(~c"abcdefghijkl", fn x -> x < ?f end) === ~c"abcde")

defmodule Take do
  @spec takewhile(xs :: [any()], f :: (any() -> boolean())) :: rs :: [any()]
  def takewhile([], _), do: []

  def takewhile(xs, f) do
    [h | r] = xs

    if f.(h) do
      [h | takewhile(r, f)]
    else
      []
    end
  end
end

IO.puts(Take.takewhile(~c"álom12" ++ [:a] ++ [~c"34brigád"], &is_integer/1) === ~c"álom12")
IO.puts(Take.takewhile(~c"abcdefghijkl", fn x -> x < ?f end) === ~c"abcde")

true
true

:ok

defmodule Take2 do
  defp takewhile([], _, acc), do: acc

  defp takewhile(xs, f, acc) do
    [h | r] = xs

    if f.(h) do
      takewhile(r, f, [h | acc])
    else
      acc
    end
  end

  @spec takewhile(xs :: [any()], f :: (any() -> boolean())) :: rs :: [any()]
  def takewhile(xs, f) do
    takewhile(xs, f, []) |> Enum.reverse() |> IO.inspect()
  end
end

IO.puts(Take2.takewhile(~c"álom12" ++ [:a] ++ [~c"34brigád"], &is_integer/1) === ~c"álom12")
IO.puts(Take2.takewhile(~c"abcdefghijkl", fn x -> x < ?f end) === ~c"abcde")

[225, 108, 111, 109, 49, 50]
true
~c"abcde"
true

:ok

Lista minden n-edik elemének kihagyásával létrejövő lista

Írjon függvényt egy olyan lista létrehozására, amelyikből a paraméterként átadott lista minden n-edik eleme, az elsőtől kezdve, ki van hagyva. Két változatban is írja meg a dropevery/2 függvényt: az első változatban ne használjon segédfüggvényt, és így akkumulátort sem, a másodikban pedig használjon jobbrekurzív segédfüggvényt akkumulátorral.

Ne használja az Enum.drop_every/2 függvényt a dropevery/2 függvény megvalósítására! (De bármilyen könyvtári függvényt használhat az eredmény ellenőrzésére.)

defmodule Drop do
  @spec dropevery(xs :: [any()], n :: integer()) :: rs :: [any()]
  def dropevery(xs, n) do
    ...
  end
end
ls = ~c"álom" ++ [:a] ++ ~c"egybrigád"
IO.inspect(Drop.dropevery(ls, 4) === ~c"lomegyrigd")
ls = ~c"abcdefghijkl"
IO.inspect(Drop.dropevery(ls, 5) === ~c"bcdeghijl")
ls = ~c"1234567"
IO.inspect(Drop.dropevery(ls, 2) === ~c"246")
ls = []
IO.inspect(Drop.dropevery(ls, 3) === [])
ls = [:a, :b, :c, :d, :e, :f, :g, :h, :i, :j, :k, :l, :m]
IO.inspect(Drop.dropevery(ls, 3) === [:b, :c, :e, :f, :h, :i, :k, :l])

Súgó A segédfüggvényt nem használó változatban, ha nincs más ötlete, használja a for jelölést, generátoraként a ../2, szűrőjeként a rem/2 műveletet, a listaelemek elérésére pedig a nemrég megírt AtEx.at/2 függvényt.

defmodule Drop do
  @spec dropevery(xs :: [any()], n :: integer()) :: rs :: [any()]
  def dropevery([], _), do: []

  def dropevery(xs, n) do
    {pre, post} = xs |> Enum.split(n)

    (pre |> Enum.drop(1)) ++ dropevery(post, n)
  end
end

ls = ~c"álom" ++ [:a] ++ ~c"egybrigád"
IO.inspect(Drop.dropevery(ls, 4) === ~c"lomegyrigd")
ls = ~c"abcdefghijkl"
IO.inspect(Drop.dropevery(ls, 5) === ~c"bcdeghijl")
ls = ~c"1234567"
IO.inspect(Drop.dropevery(ls, 2) === ~c"246")
ls = []
IO.inspect(Drop.dropevery(ls, 3) === [])
ls = [:a, :b, :c, :d, :e, :f, :g, :h, :i, :j, :k, :l, :m]
IO.inspect(Drop.dropevery(ls, 3) === [:b, :c, :e, :f, :h, :i, :k, :l])

true
true
true
true
true

true

defmodule DropH do
  defp dropevery([], _, acc), do: acc

  defp dropevery(xs, n, acc) do
    {[_ | pre], post} = xs |> Enum.split(n)
    dropevery(post, n, acc ++ pre)
  end

  @spec dropevery(xs :: [any()], n :: integer()) :: rs :: [any()]
  def dropevery(xs, n) do
    dropevery(xs, n, [])
  end
end

ls = ~c"álom" ++ [:a] ++ ~c"egybrigád"
IO.inspect(DropH.dropevery(ls, 4) === ~c"lomegyrigd")
ls = ~c"abcdefghijkl"
IO.inspect(DropH.dropevery(ls, 5) === ~c"bcdeghijl")
ls = ~c"1234567"
IO.inspect(DropH.dropevery(ls, 2) === ~c"246")
ls = []
IO.inspect(DropH.dropevery(ls, 3) === [])
ls = [:a, :b, :c, :d, :e, :f, :g, :h, :i, :j, :k, :l, :m]
IO.inspect(DropH.dropevery(ls, 3) === [:b, :c, :e, :f, :h, :i, :k, :l])

true
true
true
true
true

true

A segédfüggvényt használó változatban mellőzze a for jelölést, a ../2 műveletet, valamint a listaelemeket indexelő függvényeket.

Lista egyre rövidülő szuffixumainak listája

defmodule Tails do
  @spec tails(xs :: [any]) :: zss :: [[any]]
  # Az xs lista egyre rövidülő szuffixumainak listája zss
  def tails(xs) do
  ...
  end
end
IO.puts(Tails.tails([1, 4, 2]) === [[1, 4, 2], [4, 2], [2], []])
IO.puts(Tails.tails([:a, :b, :c, :d]) === [[:a, :b, :c, :d], [:b, :c, :d], [:c, :d], [:d], []])
IO.puts(Tails.tails([:z]) === [[:z], []])
IO.puts(Tails.tails([]) === [[]])

Súgó A tails függvénynek listák listája az eredménye, így ha üres listára alkalmazzuk, akkor olyan lista lesz a visszatérési értéke, melynek egyetlen eleme van, az üres lista.

defmodule Tails do
  @spec tails(xs :: [any]) :: zss :: [[any]]
  # Az xs lista egyre rövidülő szuffixumainak listája zss
  def tails([]), do: [[]]
  def tails([h | t]), do: [[h | t] | tails(t)]
end

IO.puts(Tails.tails([1, 4, 2]) === [[1, 4, 2], [4, 2], [2], []])
IO.puts(Tails.tails([:a, :b, :c, :d]) === [[:a, :b, :c, :d], [:b, :c, :d], [:c, :d], [:d], []])
IO.puts(Tails.tails([:z]) === [[:z], []])
IO.puts(Tails.tails([]) === [[]])

true
true
true
true

:ok

Lista egymást követő két-két eleméből képzett párok listája

Írjon olyan rekurzív függvényt, amelyik egy lista 1. és 2., 3. és 4., 5. és 6. s.í.t. elemeiből képzett párok listáját adja eredményül. Ha a listának kettőnél kevesebb eleme van, az eredmény az üres lista legyen. Ha a listának páratlan számú eleme van, az utolsót dobja el.

defmodule Pairs do
  @spec pairs(xs::[any()]) :: zs :: [any()]
  def pairs(xs), do: ...
end
zs = [{1,2}, {3,4}, {5,6}, {7,8}, {9,10}, {11,12}, {13,14}, {15,16}, {17,18}, {19,20}]
(1..20 |> Range.to_list() |> Pairs.pairs() == zs) |> IO.puts
zs = [{1,2}, {3,4}, {5,6}, {7,8}, {9,10}]
(1..11 |> Range.to_list() |> Pairs.pairs() == zs) |> IO.puts
([1] |> Pairs.pairs() == []) |> IO.puts
([1] |> Pairs.pairs() == []) |> IO.puts

defmodule Pairs do
  @spec pairs(xs :: [any()]) :: zs :: [any()]
  def pairs([]), do: []
  def pairs([_]), do: []
  def pairs([a, b | t]), do: [{a, b} | pairs(t)]
end

zs = [{1, 2}, {3, 4}, {5, 6}, {7, 8}, {9, 10}, {11, 12}, {13, 14}, {15, 16}, {17, 18}, {19, 20}]
(1..20 |> Range.to_list() |> Pairs.pairs() == zs) |> IO.puts()
zs = [{1, 2}, {3, 4}, {5, 6}, {7, 8}, {9, 10}]
(1..11 |> Range.to_list() |> Pairs.pairs() == zs) |> IO.puts()
([1] |> Pairs.pairs() == []) |> IO.puts()
([1] |> Pairs.pairs() == []) |> IO.puts()

true
true
true
true

:ok

Listában párosával előforduló elemek listája

Írjon olyan rekurzív függvényt, amelyik egy lista elemei közül az összes olyat visszaadja az eredménylistában, amelyet vele azonos értékű elem követ, azaz például két egymást követő, azonos értékű elemből egyet, három egymást követőből kettőt stb. Írjon segédfüggvényt és akkumulátort nem használó, valamint akkumulátoros segédfüggvényt használó változatokat is. Próbáljon meg egyéb változatokat is írni, pl. for jelöléssel, az Enum.zip/1 függvény alkalmazásával.

defmodule Parosan do
  @spec parosan(xs :: [any()]) :: rs :: [any()]
  # Az xs lista összes olyan elemének listája rs, amely
  # után vele azonos értékű elem áll
  def parosan xs do
  ...
  end
end
IO.puts(Parosan.parosan([:a, :a, :a, 2, 3, 3, :a, 2, :b, :b, 4, 4]) === [:a, :a, 3, :b, 4])
IO.puts(Parosan.parosan([:a, 2, 3, :a, 2, :b, 4]) === [])
IO.puts(Parosan.parosan([:a]) === [])
IO.puts(Parosan.parosan([]) === [])

defmodule Parosan do
  @spec parosan(xs :: [any()]) :: rs :: [any()]
  # Az xs lista összes olyan elemének listája rs, amely
  # után vele azonos értékű elem áll
  ## TASK: pure recursive
  def parosan([]), do: []
  def parosan([_]), do: []
  def parosan([h, h | t]), do: [h | parosan([h | t])]
  def parosan([_ | t]), do: parosan(t)
end

IO.puts(Parosan.parosan([:a, :a, :a, 2, 3, 3, :a, 2, :b, :b, 4, 4]) === [:a, :a, 3, :b, 4])
IO.puts(Parosan.parosan([:a, 2, 3, :a, 2, :b, 4]) === [])
IO.puts(Parosan.parosan([:a]) === [])
IO.puts(Parosan.parosan([]) === [])

true
true
true
true

:ok

defmodule ParosanAcc do
  @spec parosan(xs :: [any()]) :: rs :: [any()]
  # Az xs lista összes olyan elemének listája rs, amely
  # után vele azonos értékű elem áll
  ## TASK: pure recursive with acc
  defp parosanhelp([], acc), do: acc
  defp parosanhelp([_], acc), do: acc
  defp parosanhelp([h, h | t], acc), do: parosanhelp([h | t], [h | acc])
  defp parosanhelp([_, h | t], acc), do: parosanhelp([h | t], acc)
  def parosan(xs), do: parosanhelp(xs, []) |> Enum.reverse()
end

IO.puts(ParosanAcc.parosan([:a, :a, :a, 2, 3, 3, :a, 2, :b, :b, 4, 4]) === [:a, :a, 3, :b, 4])
IO.puts(ParosanAcc.parosan([:a, 2, 3, :a, 2, :b, 4]) === [])
IO.puts(ParosanAcc.parosan([:a]) === [])
IO.puts(ParosanAcc.parosan([]) === [])

true
true
true
true

:ok

defmodule ParosanFor do
  @spec parosan(xs :: [any()]) :: rs :: [any()]
  # Az xs lista összes olyan elemének listája rs, amely
  # után vele azonos értékű elem áll
  ## TASK: for comprehension
  def parosan(xs) do
  end
end

IO.puts(ParosanFor.parosan([:a, :a, :a, 2, 3, 3, :a, 2, :b, :b, 4, 4]) === [:a, :a, 3, :b, 4])
IO.puts(ParosanFor.parosan([:a, 2, 3, :a, 2, :b, 4]) === [])
IO.puts(ParosanFor.parosan([:a]) === [])
IO.puts(ParosanFor.parosan([]) === [])

false
true
true
true

:ok

Listában kulcs-érték párokban előforduló értékek listája

Egy listában többféle típusú és szerkezetű elem fordul elő, köztük {:v, v} párok is, ahol a párok első tagja a :v atom, második tagja az itt v-vel jelölt, tetszőleges érték.

Írjon olyan rekurzív függvényt, amelyik egy lista elemei közül az összes {:v, v} párban található v értéket visszaadja az eredménylistában. Írjon segédfüggvényt és akkumulátort nem használó, valamint akkumulátoros segédfüggvényt használó változatokat is. Feltétlenül írjon egyéb változatokat is , pl. Enum.map/2 és Enum.filter/2 használatával, továbbá for jelöléssel (meg fog lepődni!).

defmodule Ertekek do
  @spec ertekek(xs :: [any()]) :: vs :: [any()]
  # Az xs lista elemei közül a {:v::atom(), v::any()} mintára illeszkedő
  # párok 2. tagjából képzett lista vs
  def ertekek(xs), do: for({:v, v} <- xs, do: v)
end
Ertekek.ertekek([:alma, {:s, 3}, {:v, 1}, 3, {:v, 2}]) === [1, 2]

Súgó Ha a for komprehenzió generátorában egy mintaillesztés sikertelen, akkor az adott érték nem kerül be az eredménylistába (nem teljesült a kiválasztási feltétel), és a kiértékelés a következő listaelemmel folytatódik. Ezért a for-ral külön szűrőfeltétel használata nélkül, nagyon egyszerűen megvalósítható az elvárt működés.

defmodule Ertekek do
  @spec ertekek(xs :: [any()]) :: vs :: [any()]
  # Az xs lista elemei közül a {:v::atom(), v::any()} mintára illeszkedő
  # párok 2. tagjából képzett lista vs
  def ertekek(xs), do: for({:v, v} <- xs, do: v)
end

Ertekek.ertekek([:alma, {:s, 3}, {:v, 1}, 3, {:v, 2}]) === [1, 2]

true

Nehezebb feladatok listák rekurzív feldolgozására

Lista elején azonos értékű elemekből álló részlisták listája

Írjon függvényt olyan nemüres, folytonos részlisták előállítására, amelyek egy lista elejétől indulnak, és velük azonos értékű és elemszámú részlisták követik őket. Lehetőleg írjon többféle változatot, pl. akkumulátort használó és nem használó változatot, könyvtári függvényeket alkalmazó és nem alkalmazó változatot.

defmodule Repeated do
  @spec repeated(xs :: [any()]) :: rs :: [any()]
  def repeated(xs) do
  ...
  end
end
IO.inspect(Repeated.repeated([:a, :a, :a, 2, 3, 3, :a, :b, :b, :b, :b]) === [[:a]])
IO.inspect(Repeated.repeated([:a, :b, :b, :b, :b]) === [])
IO.inspect(Repeated.repeated([:b, :b, :b, :b]) === [[:b], [:b, :b]])
IO.inspect(Repeated.repeated([]) === [])

Súgó Ha nincs jobb ötlete, használja az Enum.take/2 és Enum.drop/2 függvényeket egy segédfüggvényben.

Listában párosával előforduló részlisták listája

Írjon függvényt egy lista összes olyan nemüres, folytonos részlistájának az előállítására, amelyet vele azonos értékű részlista követ. Lehetőleg írjon többféle változatot.

defmodule Stammering do
  @spec stammering(xs :: [any()]) :: zss :: [[any()]]
  # zss az xs lista összes olyan nemüres, folytonos részlistájából
  # álló lista, amelyet vele azonos értékű részlista követ
  def stammering(xs) do
    ...
  end
end
(Stammering1.stammering([:a, :a, :a, 2, 3, 3, :a, :b, :b, :b, :b]) ===
  [[:a], [:a], [3], [:b], [:b, :b], [:b], [:b]]) |> IO.puts()
IO.puts(Stammering1.stammering([]) === [])
IO.puts(Stammering1.stammering([:a]) === [])
IO.puts(Stammering1.stammering([:a, :a]) === [[:a]])
IO.puts(Stammering1.stammering([:a, :b]) === [])

Súgó Javasoljuk a Tails.tails/1 használatát. Felhasználhatja a Repeated1.repeated/1 vagy a Repeated2.repeated/1függvényt is.

További műveletek listákkal

For-jelölés, névtelen függvény, kifejezések

for-jelölés (for comprehension), kifejezések, függvények

Az eddigi feladatok között is voltak olyanok, amelyek megoldásához könyvtári függvényeket, for-jelölést vagy magasabb rendű függvényeket lehetett használni. Most kifejezetten kérjük a for-jelölés, a magasabb rendű függvények és más könyvtári függvények alkalmazását.

Korábban nevesített függvények megírását kértük (def és defp deklarációval), ehhez modulokat is kellett definiálni. A iex Elixir-interpretert futtató Livebookban azonban modul definiálása nélkül is lehet kifejezéseket kiértékeltetni, többek között névtelen függényeket változóhoz kötni. Lássunk egy kis példát!

Kis példák névtelen függvények definiálására

Először egy kis névtelen segédfüggvényt írunk annak eldöntésére, hogy a paramétere magánhangzó-e a magyar ábécé szerint (nagy- és kisbetű között nem teszünk különbséget). A paramétert egykarakteres sztringként adjuk át.

Sajnos, specifikációt csak függvénydefinícióhoz lehet írni, ezért itt kommentbe tesszük, hogy segítse a megértést.

# @spec is_vowel(string()) :: boolean()
is_vowel = fn c -> String.contains?("aáeéiíoóöőuúüű", String.downcase(c)) end
IO.puts(is_vowel.("É"))
IO.puts(is_vowel.("ő"))
IO.puts(is_vowel.("V"))

Emlékezzünk rá, hogy egy névtelen függvény vagy egy névhez kötött (de nem def vagy defp deklarációval létrehozott) függvény alkalmazásakor a függvényérték és a paraméter közé egy .-ot kell tenni.

Mivel most néhány példamegoldást mutatunk be, két cellában is ugyanaz a (vagy nagyon hasonló) programkód van. A felső, halványzöld keretes cella szövege nem írható át (csak szerkesztő módban), nem futtatható, de másolható. Az alsó cellában a kód átírható, futtatható. Javasoljuk, hogy ne csak futtassa, hanem módosítsa is a kódot, írjon más, esetleg jobb megoldásokat.

Most írjunk olyan névtelen függvényt, amelyik az egykarakteres sztringként megkapott paraméterét, ha az magánhangzó, nagybetűssé, ha mássalhangzó, kisbetűssé konvertálja.

A már bevezetett változókat használhatjuk a további cellákban.

# @spec vow_up_cons_down(string()) :: string()
vow_up_cons_down = fn c -> if is_vowel.(c), do: String.upcase(c), else: String.downcase(c) end
IO.puts(vow_up_cons_down.("É"))
IO.puts(vow_up_cons_down.("ő"))
IO.puts(vow_up_cons_down.("V"))

Most írjunk olyan névtelen függvényt for jelöléssel, amelyik a sztringként megkapott paraméterében az összes magánhangzót nagybetűssé, az összes mássalhangzót kisbetűssé konvertálja.

# @spec my_conv(string()) :: string()
my_conv = fn s ->
  for(c <- to_charlist(s), do: vow_up_cons_down.(to_string([c]))) |> Enum.join()
end
IO.puts(my_conv.("hátasló"))
IO.puts(my_conv.("hatásvizsgálat"))
IO.puts(my_conv.("Üllői úti fák"))
IO.puts(my_conv.("Táncórák Idősebbeknek Május 35-étől"))

A névtelen függvény definiálásának van tömörebb változata is:

# @spec my_conv(string()) :: string()
my_conv = &(for(c <- to_charlist(&1), do: vow_up_cons_down.(to_string([c]))) |> Enum.join())
IO.puts(my_conv.("hátasló"))
IO.puts(my_conv.("hatásvizsgálat"))
IO.puts(my_conv.("Üllői úti fák"))
IO.puts(my_conv.("Táncórák Idősebbeknek Május 35-étől"))

Természetes szám valódi osztói

Egy természetes szám valódi osztóinak nevezzük az 1-en és önmagán kívüli pozitív osztóit.

Írjon olyan kifejezést/függvényt a for jelölés felhasználásával, amelyik egy listában visszaadja a paraméterként átadott természetes szám valódi osztóit.

# @spec proper_divisors(i :: integer()) :: ds :: [integer()]
# Az i természetes szám valódi osztóinak listája ds
proper_divisors = ...
(proper_divisors.(10) === [2, 5]) |> IO.inspect(charlists: :as_list)
(proper_divisors.(23) === []) |> IO.inspect(charlists: :as_list)
(proper_divisors.(48) === [2, 3, 4, 6, 8, 12, 16, 24]) \
 |> IO.inspect(charlists: :as_list)
(proper_divisors.(128) === [2, 4, 8, 16, 32, 64]) \
 |> IO.inspect(charlists: :as_list)

Súgó

Egy $k$ természetes szám valódi osztóit a legegyszerűbben úgy találhatja meg, hogy a $k$-t rendre elosztja a $2$ és $k/2$ közötti egészekkel, és ha az egészosztásnak nincs maradéka, akkor az adott szám osztója $k$-nak.

Összetett számok

Összetett számnak nevezzük azt a természetes számot, amelynek van valódi osztója. A legkisebb összetett szám a 4.

Írjon olyan kifejezést/függvényt a for jelölés felhasználásával, amelyik egy listában visszaadja a függvénynek paraméterként átadott természetes számnál nem nagyobb összes összetett számot, 4-től kezdve. A függvényben felhasználhatja a szám valódi osztóit előállító függvényt, amit az előbb írt meg.

# @spec composite_numbers(i :: integer()) :: ns :: [integer()]
# Az i-nél nem nagyobb összetett számok listája ns
composite_numbers =
(composite_numbers.(11) === [4, 6, 8, 9, 10]) |> IO.inspect(charlists: :as_list)
(composite_numbers.(17) === [4, 6, 8, 9, 10, 12, 14, 15, 16]) \
 |> IO.inspect(charlists: :as_list)

Hatékonyabb megoldás

Írjon olyan megoldást az előző feladatra, amelyik nem állítja elő a valódi osztók listáját.

Az $n$ természetes szám összetett, ha osztható

a $2$ és $\sqrt n$ közötti prímszámok bármelyikével;
$2$-vel vagy a $3$ és $\sqrt n$ közötti páratlan egészek bármelyikével.

Az első módszer gyorsabb, de ha a prímszámok előállítása nem triviális, elég hatékony a második módszer is. További hatékonyságnövelő lehetőségekről olvashat pl. itt: pl. https://en.wikipedia.org/wiki/Primality_test.

composite_numbers_faster = &for i <- 4..&1, composite?.(i), do: i
(composite_numbers_faster.(11) === [4, 6, 8, 9, 10] ) \
 |> IO.inspect(charlists: :as_list)
(composite_numbers_faster.(21) === [4, 6, 8, 9, 10, 12, 14, 15, 16, 18, 20, 21])\
 |> IO.inspect(charlists: :as_list)

Súgó

Javasoljuk, hogy a megoldást bontsa lépésekre: állítsa elő a szám összetett voltának vizsgálatához használandó osztókat; állapítsa meg, hogy a szám összetett szám-e; állítsa elő az összetett számok listáját a kért tartományban. Fontolja meg az alább felsorolt függvények használatát.

A Kernel modulban definiált ..///3 operátor operandusainak egész számoknak kell lenniük, ezért ha a felső határ beállítására a :math.sqrt/1 függvényt használja, egész számmá kell konvertálni (vö. round/1, floor/1, ceil/1 függvények).
Az Enum.to_list/1 függvény tetszőleges felsorolható sorozatot alakít át listává, így tartomány-típusú értéksorozatot is.
Az Enum.reduce/3 függvény egy lista összes elemére alkalmaz egy kétoperandusú függvényt: ha pl. egy szám összetett voltát akarjuk vizsgálni vele, akkor olyan függvényt kell átadnunk paraméterként, amelyik az adott számnak a sorozat egy elemével való oszthatósága esetén igaz, egyébként hamis értékkel tér vissza.

# @spec probes(i :: integer()) :: ps :: [integer()]
# A 2-t, továbbá a 3 és a :math.sqrt(i) közé eső egészeket tartalmazó lista ps
probes = ... 
# @spec composite?(i :: integer()) :: b :: boolean()
# b igaz, ha i összetett szám
composite? = ...
# @spec composite_numbers_faster(i :: integer()) :: ns :: [integer()]
# Az i-nél nem nagyobb összetett számok listája ns
composite_numbers_faster = ...

A megoldást, ha a javaslatunkat megfogadta, három kis – esetleg több – lépésre bontotta, mindegyikre egy-egy névtelen (de változóhoz kötött) függvényt írt, így ezeket könnyebb volt megérteni, és a helyességüket könnyebb volt belátni. Mivel a funkcionális nyelvekben a függvényhívás nagyon hatékonyan van megoldva, ez a jó és követendő gyakorlat: minden kicsit is összetett függvényt több egyszerűbb függvényből rakjunk össze, és ahol csak lehet, használjuk a hatékonyan megvalósított és sokat tesztelt könyvtári függvényeket.

Other notebooks:

Anima Logica
@AnimaLogica

ExZarr

Xarray Introduction to Zarr: Groups and Attributes

xarray_zarr_intro.livemd

advanced data-science ex_zarr nx kino

2026-10-4
NISHIGUCHI Masatoshi
@mnishiguchi

livebooks

タイタニック問題

titanic.livemd

tutorial advanced data-science nx axon exla csv statistics kino_vega_lite

2024-2-28
Poeticoding Ltd.
@poeticoding

yolo_elixir

YOLOX

yolox.livemd

advanced ai yolo nx exla image evision req kino kino_yolo

2026-7-7
@DeSchoel

Elixir_Curriculum

GenServer Drills

genserver_drills.livemd

tutorial advanced gen-server jason kino youtube hidden_cell

2026-1-10
Ryo Wakabayashi
@RyoWakabayashi

elixir-learning

分散処理ワーカー4

distributed_worker_4.livemd

advanced data-science iot nx evision flow kino

2026-7-7
Hugo Baraúna
@hugobarauna

livebook-notebooks

Teams Server

teams_server.livemd

tutorial advanced otp phoenix_playground kino livebook_proto

2026-7-7
Ammar Massoud
@ammar-mohamed-massoud

Dockyard-Academy

Metaprogramming

metaprogramming.livemd

tutorial advanced jason kino youtube hidden_cell

2026-7-7

Back