AoC 2021 - Day 4: Giant Squid
Setup
Mix.install(
[
{:kino, "~> 0.4.1"}
],
consolidate_protocols: false
)input = Kino.Input.textarea("Please paste your input:")Part 1
You’re already almost 1.5km (almost a mile) below the surface of the ocean, already so deep that you can’t see any sunlight. What you can see, however, is a giant squid that has attached itself to the outside of your submarine.
Maybe it wants to play bingo?
Bingo is played on a set of boards each consisting of a 5x5 grid of numbers. Numbers are chosen at random, and the chosen number is marked on all boards on which it appears. (Numbers may not appear on all boards.) If all numbers in any row or any column of a board are marked, that board wins. (Diagonals don’t count.)
The submarine has a bingo subsystem to help passengers (currently, you and the giant squid) pass the time. It automatically generates a random order in which to draw numbers and a random set of boards (your puzzle input). For example:
7,4,9,5,11,17,23,2,0,14,21,24,10,16,13,6,15,25,12,22,18,20,8,19,3,26,1
22 13 17 11 0
8 2 23 4 24
21 9 14 16 7
6 10 3 18 5
1 12 20 15 19
3 15 0 2 22
9 18 13 17 5
19 8 7 25 23
20 11 10 24 4
14 21 16 12 6
14 21 17 24 4
10 16 15 9 19
18 8 23 26 20
22 11 13 6 5
2 0 12 3 7
After the first five numbers are drawn (7, 4, 9, 5, and 11), there are no winners, but the boards are marked as follows (shown here adjacent to each other to save space):
22 13 17 11 0 3 15 0 2 22 14 21 17 24 4
8 2 23 4 24 9 18 13 17 5 10 16 15 9 19
21 9 14 16 7 19 8 7 25 23 18 8 23 26 20
6 10 3 18 5 20 11 10 24 4 22 11 13 6 5
1 12 20 15 19 14 21 16 12 6 2 0 12 3 7
After the next six numbers are drawn (17, 23, 2, 0, 14, and 21), there are still no winners:
22 13 17 11 0 3 15 0 2 22 14 21 17 24 4
8 2 23 4 24 9 18 13 17 5 10 16 15 9 19
21 9 14 16 7 19 8 7 25 23 18 8 23 26 20
6 10 3 18 5 20 11 10 24 4 22 11 13 6 5
1 12 20 15 19 14 21 16 12 6 2 0 12 3 7
Finally, 24 is drawn:
22 13 17 11 0 3 15 0 2 22 14 21 17 24 4
8 2 23 4 24 9 18 13 17 5 10 16 15 9 19
21 9 14 16 7 19 8 7 25 23 18 8 23 26 20
6 10 3 18 5 20 11 10 24 4 22 11 13 6 5
1 12 20 15 19 14 21 16 12 6 2 0 12 3 7
At this point, the third board wins because it has at least one complete row or column of marked numbers (in this case, the entire top row is marked: 14 21 17 24 4).
The score of the winning board can now be calculated. Start by finding the sum of all unmarked numbers on that board; in this case, the sum is 188. Then, multiply that sum by the number that was just called when the board won, 24, to get the final score, 188 * 24 = 4512.
To guarantee victory against the giant squid, figure out which board will win first. What will your final score be if you choose that board?
defmodule Board do
empty_board = Tuple.duplicate(Tuple.duplicate(false, 5), 5)
@enforce_keys [:numbers]
defstruct numbers: %{}, grid: empty_board
def new(numbers) when is_map(numbers) do
%Board{numbers: numbers}
end
def mark(%Board{numbers: numbers} = board, number) do
case numbers do
%{^number => {row, col}} ->
put_in(board, [Access.key(:grid), Access.elem(row), Access.elem(col)], true)
%{} ->
board
end
end
def unmarked_sum(%Board{numbers: numbers, grid: grid}) do
Enum.sum(
for {number, {row, col}} <- numbers,
grid |> elem(row) |> elem(col) == false,
do: number
)
end
def won?(%Board{grid: grid}) do
row_won?(grid) or column_won?(grid)
end
defp column_won?(grid) do
Enum.any?(0..4, fn col ->
Enum.all?(0..4, fn row -> grid |> elem(row) |> elem(col) end)
end)
end
defp row_won?(grid) do
Enum.any?(0..4, fn row ->
elem(grid, row) == {true, true, true, true, true}
end)
end
enddefimpl Inspect, for: Board do
import Inspect.Algebra
def inspect(%Board{grid: grid, numbers: numbers}, _opts) do
inverse = for {k, v} <- numbers, into: %{}, do: {v, k}
contents =
for row <- 0..4 do
for col <- 0..4 do
string = String.pad_leading(Integer.to_string(inverse[{row, col}]), 2)
if grid |> elem(row) |> elem(col), do: color(:red, string), else: string
end
|> Enum.intersperse(" ")
|> IO.iodata_to_binary()
end
|> Enum.intersperse(line())
|> concat()
force_unfit(
concat([
"~B",
"\"",
"\"",
"\"",
line(),
contents,
line(),
"\"",
"\"",
"\""
])
)
end
defp color(color, string) do
IO.ANSI.format([color, string])
|> IO.iodata_to_binary()
end
end[draw | grids] =
input
|> Kino.Input.read()
|> String.split("\n", trim: true)
boards =
grids
|> Enum.chunk_every(5)
|> Enum.map(fn rows ->
Board.new(
for {line, row} <- Enum.with_index(rows, 0),
{number, col} <- Enum.with_index(String.split(line), 0),
into: %{} do
{String.to_integer(number), {row, col}}
end
)
end)
numbers =
draw
|> String.split(",")
|> Enum.map(&String.to_integer/1)defmodule BoardSigil do
defmacro sigil_B({:<<>>, _, [grid]}, []) do
rows = String.split(grid, "\n")
for {line, row} <- Enum.with_index(rows, 0),
{number, col} <- Enum.with_index(String.split(line), 0),
into: %{} do
{String.to_integer(number), {row, col}}
end
|> Board.new()
|> Macro.escape()
end
endimport BoardSigil, only: :sigils
{number, board = %Board{}} =
Enum.reduce_while(numbers, boards, fn number, boards ->
boards = Enum.map(boards, &Board.mark(&1, number))
if board = Enum.find(boards, &Board.won?/1) do
{:halt, {number, board}}
else
{:cont, boards}
end
end)number * Board.unmarked_sum(board)Part 2
On the other hand, it might be wise to try a different strategy: let the giant squid win.
You aren’t sure how many bingo boards a giant squid could play at once, so rather than waste time counting its arms, the safe thing to do is to figure out which board will win last and choose that one. That way, no matter which boards it picks, it will win for sure.
In the above example, the second board is the last to win, which happens after 13 is eventually called and its middle column is completely marked. If you were to keep playing until this point, the second board would have a sum of unmarked numbers equal to 148 for a final score of 148 * 13 = 1924.
Figure out which board will win last. Once it wins, what would its final score be?
{number, board = %Board{}} =
Enum.reduce_while(numbers, boards, fn number, boards ->
boards = Enum.map(boards, &Board.mark(&1, number))
case Enum.reject(boards, &Board.won?/1) do
[] ->
# We can assume there was only one board left,
# otherwise AoC gave me a bad input.
[board] = boards
{:halt, {number, board}}
boards ->
{:cont, boards}
end
end)number * Board.unmarked_sum(board)
