Stock Market Turnover Ratio

Mix.install([
  {:fred, "~> 0.5.0"},
  {:vega_lite, "~> 0.1.11"},
  {:kino_vega_lite, "~> 0.1.13"}
])

Introuction

<- Back to index

require Explorer.DataFrame

alias VegaLite, as: Vl
alias Explorer.DataFrame

# API key pulled from Livebook secrets
Application.put_env(:fred, :api_key, System.fetch_env!("LB_FRED_API_KEY"))

# Attach the default logger to keep an eye on requests
Fred.Telemetry.Logger.attach(level: :info)

# Set the start date
observation_start = ~D[1975-01-01]

# Required Fred series IDs
turnover_series = "DDEM01USA156NWDB"
recession_series = "USREC"

:ok

# Fetch metadata on the unemployment series and output it
{:ok, %{"seriess" => [metadata | _]}} = Fred.Series.get(turnover_series)

# Print out some of the metadata from the series
IO.puts("""
Title:       #{metadata["title"]}
Frequency:   #{metadata["frequency"]}
Units:       #{metadata["units"]}
Seasonal:    #{metadata["seasonal_adjustment"]}
Last Update: #{metadata["last_updated"]}
""")

:ok

# Fetch the time series for the stock market turnover as a DataFrame
data_frame =
  turnover_series
  |> Fred.Series.observations_as_data_frame(
    observation_start: observation_start,
    frequency: :a,
    rename: %{turnover_series => "turn_over_ratio"}
  )

min_date = Explorer.Series.min(data_frame["date"])
max_date = Explorer.Series.max(data_frame["date"])

Kino.DataTable.new(data_frame)

# Fetch the recession indicator for the same date range
{:ok, %{"observations" => recession_data}} =
  Fred.Series.observations(recession_series,
    observation_start: observation_start,
    frequency: :m
  )

recession_periods =
  recession_data
  |> Enum.flat_map(fn
    %{"value" => "."} ->
      []

    %{"value" => value, "date" => date} ->
      [{Date.from_iso8601!(date), value}]
  end)
  |> Enum.chunk_by(fn {_date, value} -> value end)
  |> Enum.flat_map(fn
    [{_date, "0"} | _] ->
      []

    data ->
      [Enum.map(data, fn {date, _value} -> date end)]
  end)
  |> Enum.map(fn chunk ->
    {start, stop} =
      Enum.min_max_by(chunk, fn date -> date end, Date)

    %{start: start, stop: stop}
  end)

:ok

# Plot the two separate series
[
  width: 700,
  height: 400,
  title: "#{metadata["title"]} (#{min_date} - #{max_date})"
]
|> Vl.new()
|> Vl.layers([
  # Gray recession bands
  Vl.new()
  |> Vl.data_from_values(recession_periods)
  |> Vl.mark(:rect, color: "#3f3f46", opacity: 0.25)
  |> Vl.encode_field(:x, "start", type: :temporal)
  |> Vl.encode_field(:x2, "stop", type: :temporal),
  Vl.new()
  |> Vl.data_from_values(data_frame)
  |> Vl.mark(:line, tooltip: true, color: "#2563eb")
  |> Vl.encode_field(:x, "date",
    type: :temporal,
    title: "Date",
    axis: [format: "%Y"]
  )
  |> Vl.encode_field(:y, "turn_over_ratio",
    type: :quantitative,
    title: metadata["units"]
  )
])