US Market Indices

Mix.install([
  {:fred, "~> 0.5.0"},
  {:vega_lite, "~> 0.1.11"},
  {:kino_vega_lite, "~> 0.1.13"}
])

Introuction

<- Back to index

require Explorer.DataFrame

alias VegaLite, as: Vl
alias Explorer.DataFrame
alias Explorer.Series

# API key pulled from Livebook secrets
Application.put_env(:fred, :api_key, System.fetch_env!("LB_FRED_API_KEY"))

# Attach the default logger to keep an eye on requests
Fred.Telemetry.Logger.attach(level: :info)

# Set the start date
observation_start = ~D[2015-01-01]

# Stock market turnover ratio series IDs and recession ID
recession_series = "USREC"

us_market_indexes =
  %{
    "DJIA" => "dow_30",
    "NASDAQ100" => "nasdaq_100",
    "SP500" => "sp_500"
  }

:ok

# Fetch metadata on the unemployment series and output it
Enum.each(us_market_indexes, fn {id, _name} ->
  {:ok, %{"seriess" => [metadata | _]}} = Fred.Series.get(id)

  # Print out some of the metadata from the series
  IO.puts("""
  Title:       #{metadata["title"]}
  Frequency:   #{metadata["frequency"]}
  Units:       #{metadata["units"]}
  Seasonal:    #{metadata["seasonal_adjustment"]}
  Last Update: #{metadata["last_updated"]}
  """)
end)

data_frame =
  us_market_indexes
  |> Enum.map(fn {id, _name} ->
    id
  end)
  |> Fred.Series.observations_as_data_frame(
    observation_start: observation_start,
    frequency: :d,
    rename: us_market_indexes
  )
  |> DataFrame.pivot_longer(Enum.map(us_market_indexes, fn {_id, name} -> name end),
    names_to: "series",
    values_to: "price"
  )
  |> DataFrame.sort_by(asc: date)

min_date = Series.min(data_frame["date"])
max_date = Series.max(data_frame["date"])

Kino.DataTable.new(data_frame)

# Fetch the recession indicator for the same date range
{:ok, %{"observations" => recession_data}} =
  Fred.Series.observations(recession_series,
    observation_start: observation_start,
    frequency: :m
  )

recession_periods =
  recession_data
  |> Enum.flat_map(fn
    %{"value" => "."} ->
      []

    %{"value" => value, "date" => date} ->
      [{Date.from_iso8601!(date), value}]
  end)
  |> Enum.chunk_by(fn {_date, value} -> value end)
  |> Enum.flat_map(fn
    [{_date, "0"} | _] ->
      []

    data ->
      [Enum.map(data, fn {date, _value} -> date end)]
  end)
  |> Enum.map(fn chunk ->
    {start, stop} =
      Enum.min_max_by(chunk, fn date -> date end, Date)

    %{start: start, stop: stop}
  end)

:ok

# Plot the two separate series
Vl.new(width: 1000, height: 400, title: "US Market Indexes (#{min_date} - #{max_date})")
|> Vl.layers([
  # Gray recession bands
  Vl.new()
  |> Vl.data_from_values(recession_periods)
  |> Vl.mark(:rect, color: "#3f3f46", opacity: 0.25)
  |> Vl.encode_field(:x, "start", type: :temporal)
  |> Vl.encode_field(:x2, "stop", type: :temporal),

  # Unemployment area
  Vl.new()
  |> Vl.data_from_values(data_frame)
  |> Vl.mark(:line, tooltip: true, color: "#2563eb")
  |> Vl.encode_field(:x, "date",
    type: :temporal,
    title: "Date",
    axis: [format: "%Y"]
  )
  |> Vl.encode_field(:y, "price",
    type: :quantitative,
    title: "Value of Index"
  )
  |> Vl.encode_field(:color, "series", type: :nominal)
])